/*
  Web Server

 A simple web server that shows the value of the 
 DHT11 temperature and humidity sensor.
 Uses an Arduino Wiznet 5100 Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * DHT11 attached to digital pin 8.

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 modified 02 Sept 2015
 by Arturo Guadalupi
 modified 07 Jan 2017
 by Mark Giovannetti

 */

#include <SPI.h>
#include <Ethernet.h>
#include <dht11.h>

DHT11 DHT11;  // Declare our sensor object

#define DHT11PIN 8  // DHT11 attach to digital pin 8 on controller board

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 1, 177);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
EthernetServer server(80);

int temperature = -999;  // Default values to act as sentinels
int humidity = -999;     // -999  means no data available

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {

  // listen for incoming clients
  EthernetClient client = server.available();
  
  if (client) {
    Serial.println("new client");
    
    // read the value returned from sensor
    Serial.print("Checking DHT11,\t");
    int chk = DHT11.read(DHT11PIN);
    switch (chk)
    {
      case DHTLIB_OK:  
      Serial.print("OK \t"); 
      temperature = DHT11.temperature;
      humidity = DHT11.humidity;
      break;
      case DHTLIB_ERROR_CHECKSUM: 
      Serial.print("Checksum error,\t"); 
      temperature = -999;
      humidity = 0; 
      break;
      case DHTLIB_ERROR_TIMEOUT: 
      temperature = 0;
      humidity = -999; 
      Serial.print("Time out error,\t"); 
      break;
      default: 
      temperature = -999;
      humidity = -999; 
      Serial.print("Unknown error,\t"); 
      break;
    }
    Serial.println();
    // Display values to serial log
    Serial.print("Tem: ");
    Serial.print(DHT11.temperature); //print the temperature on serial monitor
    Serial.println(" C");
    Serial.print("Hum: ");
    Serial.print(DHT11.humidity); //print the humidity on serial monitor
    Serial.println(" %"); 
    Serial.println();

    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/plain");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println();
          client.print(temperature);
          client.print(" ");
          client.print(humidity);
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(5);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}